Perl/모듈

1. 다른 파일을 include 하기

1.1. do

1.2. require

1.3. use

2. perldoc use 번역

2.1. 참고: 'use VERSION'의 사이드 이펙트

3. @INC 변경하기

3.1. 환경변수로 모듈 디렉토리 추가

3.2. 명령행 인자 -I

4. import, Exporter

4.1. %EXPORT_TAGS

4.2. 객체 지향 모듈의 경우

4.3. import 직접 구현하기

5. 패키지

5.1. package 의 스코프

5.2. __PACKAGE__ 상수

6. 기타

7. Comments

1. 다른 파일을 include 하기

1.1. do

• 파일을 못 찾으면 undef반환, $! 설정
• 찾았으나 컴파일 안 되면 undef반환, $@ 설정
• 성공적으로 수행되면 마지막으로 계산한 식의 값을 반환

                   # read in config files: system first, then user
                   for $file ("/share/prog/defaults.rc",
                              "$ENV{HOME}/.someprogrc")
                  {
                       unless ($return = do $file) {
                           warn "couldn't parse $file: $@" if $@;
                           warn "couldn't do $file: $!"    unless defined $return;
                           warn "couldn't run $file"       unless $return;
                       }
                   }

1.2. require

require Monty::Python;
# @INC 패쓰에서 MOnty/Python.pm을 찾는다

1.3. use

# 아래와 같이 적어도, 두개의 모듈이 다 include된다
if ($graphical) {
   use MyProgram::Graphical;
} else {
   use MyProgram::Text;
}

2. perldoc use 번역

use Module VERSION LIST
use Module VERSION
use Module LIST
use Module
use VERSION

    BEGIN { require Module; Module->import( LIST ); }

• 위와 같이 한 것과 완전히 동일하되, Module 부분이 bareword여야만 한다는 것이 다르다.

    use v5.6.1;    # 컴파일타임에 버전 체크
    use 5.6.1;     # 마찬가지
    use 5.006_001; # 마찬가지; 하위호완성 유지를 위해 권장됨

    use Module ();

    BEGIN { require Module }

    use constant;
    use diagnostics;
    use integer;
    use sigtrap  qw(SEGV BUS);
    use strict   qw(subs vars refs);
    use subs     qw(afunc blurfl);
    use warnings qw(all);
    use sort     qw(stable _quicksort _mergesort);

    use if $] < 5.008, "utf8";
    use if WANT_WARNINGS, warnings => qw(all);

    no integer;
    no strict 'refs';
    no warnings;

2.1. 참고: 'use VERSION'의 사이드 이펙트

• say
• state
• given-which

use 5.010;
say 'I can use Switch!';  # imported say()

given ($ARGV[0]) {        # imported given()
    when( defined ) { some_sub() }
};

sub some_sub {
    state $n = 0;         # imported state()
    say "$n: got a defined argument";
}

use 5.010;     # 묵시적인 임포트
no feature;    # 곧바로 되돌림

# 당신이 따로 작성한 say()
sub say {
    # something that you want to do
}

use 5.010;
no feature qw(say);   # state()와 given()은 남겨둠

sub say {
    # something that you want to do
}

• unicode_strings
• strict

use 5.012;
# now strictures are on

$foo = 1;   # compile-time error!

BEGIN { require 5.012 }

$foo = 1;  # still a compile-time error

use 5.012;
no feature;
no strict;

my $foo = 1;

$fo0++;  # 확실히 된다, 계속 진행해서 에러를 만들라

BEGIN {
    die "Unsupported version"
        unless $] >= 5.010 and $] < 5.011
}

• Perl 5.9.5 이후부터는 use VERSION은 새로운 기능들을 임포트한다.
• BEGIN { require VERSION }도 새로운 기능들을 임포트한다.
• no feature나 no strict를 써서 원하지 않은 기능을 언임포트하라.
• perl 버전만을 제한하는 건 $] 변수를 사용하여 하라.

3. @INC 변경하기

BEGIN {
   push @INC, "my/module/directory";
}
use Wibble;

# lib 프라그마를 사용하면 더 쉽다
use lib "my/module/directory";
use Wibble;

# 이렇게는 안 된다
my $LIB_DIR = '/home/gilligan/lib';
...
use lib $LIB_DIR;     # BROKEN
use Navigation::SeatOfPants;

# 아래와 같이
use constant LIB_DIR => '/home/gilligan/lib';
...
use lib LIB_DIR;
use Navigation::SeatOfPants;

use FindBin qw($Bin);
use lib $Bin;         # 스크립트가 있는 디렉토리
use lib "$Bin/lib";   # 서브디렉토리
use lib "$Bin/../lib";

3.1. 환경변수로 모듈 디렉토리 추가

export PERL5LIB=/Users/home/Ginger

3.2. 명령행 인자 -I

perl -I/home/skipper/perl-lib /home/skipper/bin/get_us_home

4. import, Exporter

use Wibble ("wobble", "bounce", "boing");
# 위는 Wibble 모듈을 로드한 후 다음을 실행한다
Wibble::import("wobble", "bounce", "boing");

# Wibble 모듈 샘플
package Wibble;
use warnings;
use strict;
use Exporter;                             # Exporter 를 사용
our @ISA = qw(Exporter);                  # Exporter 상속
our @EXPORT    = qw(bounce);              # 기본으로 export될 서브루틴
our @EXPORT_OK = qw(wobble bounce boing); # export가능한 서브루틴들

sub wobble { print "wobble\n"; mine(); }
sub bounce { warn  "bounce\n"; }
sub boing  { die   "boing!\n"; }
sub mine   { print "not be exported\n"; }

1;

4.1. %EXPORT_TAGS

use Fcntl qw( :flock );    # import all flock constants

• DEFAULT - 임포트 리스트가 없을 때 임포트되는 것과 동일

• 해쉬 키는 태그 이름 (콜론 없이)
• 해쉬 값은 심볼들의 익명 배열. 이 심볼들은 @EXPORT 또는 @EXPORT_OK에 있는 것이어야 함

package Navigate::SeatOfPants;
use base qw(Exporter);

our @EXPORT    = qw(guess_direction_toward);
our @EXPORT_OK = qw(
                get_north_from_professor
                according_to_GPS
                ask_the_skipper_about
                );

our %EXPORT_TAGS = (
        all       => [ @EXPORT, @EXPORT_OK ],   # export할 수 있는 전부
        gps       => [ qw( according_to_GPS ) ],
        direction => [ qw(
                get_north_from_professor
                according_to_GPS
                guess_direction_toward
                ask_the_skipper_about
                ) ],
        );

4.2. 객체 지향 모듈의 경우

package My::OOModule::Base;
our @EXPORT = (  ); # you may even omit this line
use base qw(Exporter);

• export_to_level
• require_version
• export_fail
• unimport

4.3. import 직접 구현하기

sub import {
  no strict 'refs';
  my $debug = grep { $_ eq 'debug' } @_;       # 임포트 리스트에 'debug'가 있으면 디버깅 옵션 활성화
  my( $package, $file, $line ) = caller;       # caller는 자신을 부른 곳의 정보를 반환
  warn "I was called by $package in $file\n" if $debug;
  for (qw(filename basename fileparse)) {
    *{$package . "::$_"} = \&$_;               # 세 개의 심볼을 호출한 쪽의 패키지에 export 함
  }
}

5. 패키지

5.1. package 의 스코프

• 다음 package 지시자가 올 때까지, 또는
• 중괄호 블럭 안에서 선언된 경우 해당 블럭의 끝까지

package Navigation;

{  # start scope block
  package main;  # now in package main

  sub turn_toward_heading {  # main::turn_toward_heading
    .. code here ..
  }

}  # end scope block

# back to package Navigation

sub turn_toward_port { # Navigation::turn_toward_port
  .. code here ..
}

• ARGV, ARGVOUT, ENV, INC, SIG, STDERR, STDIN, STDOUT
• punctuation mark variables: $_, $2, 등등

5.2. __PACKAGE__ 상수

• 출처: [Perl Training Australia - Packages and __PACKAGE__]

        package Music::Artist;        # Inherit from the Music::DBI class (defined elsewhere)
        use base 'Music::DBI';        # These records are pulled from this database table

        Music::Artist->table('artist');    # 이렇게 패키지명을 직접 적는 대신
        __PACKAGE__->table('artist');      # __PACKAGE__ 사용

        $hash{__PACKAGE__} = 1;      # 이렇게 쓰면
        $hash{"__PACKAGE__"} = 1;    # 이것과 동일한 결과. 즉 "__PACKAGE__"라는 키가 된다.

        # 패키지 명으로 치환하기 위해서 상수값을 먼저 계산하게 해야 한다.
        $hash{__PACKAGE__ . ""} = 1; # 빈 스트링을 붙여주거나

        my $package = __PACKAGE__;   # 변수에 먼저 넣은 후 사용
        $hash{$package} = 1;

6. 기타

• [A Look at Perl: A Look At My Utility Library] - 자신이 자주 사용하는 것들을 모아두는 모듈 파일의 기본 뼈대 작성법
  • [A Look at Perl: A Place for the Tests] - 테스트 코드 넣기
  • [A Look at Perl: A Look at Dumping]
  • [A Look at Perl: A Look at Finding Out-of-Date Files]

• [코드 재사용을 위한 Perl 모듈 만들기] - 비슷한 내용

7. Comments