UseModWiki소스수정/Vim플러그인

1. Vim 플러그인

1.1. 알려진 문제점

1.2. plugin/vim.pl 추가

1.3. wiki.css 수정

1.4. 추가 업데이트 내역

1.5. 사용자 의견

1. Vim 플러그인

• 필수 요구 사항:
  • /PlugIn 패치가 되어 있을 것
  • [vim]이 설치되어 있을 것
    • vim-enhanced 패키지가 설치되어 있어야 하는데, 웹호스팅 업체의 경우 설치되어 있지 않았을 수도 있다.
• 선택 요구 사항:
  • Digest::MD5 모듈이 설치되어 있으면 좋다.

• 사용법:
  • 다음과 같이 호출한다.

 {{{#!vim [c|sh|...] [number]
 code
 }}}

• [c|sh|...] - 사용할 신택스
  • 서버에 설치되어 있는 vim 이 지원하는 신택스
• [number] - number 라는 옵션을 주면 행번호를 출력한다.
• 한 번 생성된 html 출력은 upload 디렉토리 아래 vim 디렉토리 아래 저장되어, 다음 번 호출시에는 이 html파일을 읽어서 보여준다. 따라서, vim을 호출하는 오버헤드가 크기 때문에 코드 블럭의 갯수가 많으면 처리에 시간이 많이 걸리지만, 일단 html출력이 저장되면 {{{언어 }}}를 사용하는 것보다 더 빨라진다.

• 사용예

#!/usr/bin/perl
if ($condition) {
    print "Hello, World!\n";
}

• 부작용: 딱히 없을 듯

1.1. 알려진 문제점

vim 6.4 이후부터, 변환된 출력의 글꼴 색상이 매우 이상하게 나오고 불필요해보이는 밑줄까지 그어져서 나오는 문제가 있다.

• [vim의 Ex mode실행으로 2html 실행할 때 터미널 문제가... | KLDP]
• VimPluginTest

현재 딱히 해결방법은 없고, GyparkWiki에서는 다음과 같이 임시로 처리해둔 상태:

• Raymundo의 사용자 계정에다가 6.3버전을 따로 설치한 후,
• vim.pl 플러그인 파일을 myplugin/ 디렉토리에 복사하고
• 복사된 myplugin/vim.pl 파일에서 vim 실행파일 경로를 직접 지정

sub plugin_vim {
    my ($content, @opt) = @_;
#    my $vim = "vim";       # PATH of vim
    my $vim = "/home/gypark/local/bin/vim63";       # 이런 식으로
    my $tohtml = "syntax/2html.vim";
    ...
}

1.2. plugin/vim.pl 추가

# vim plugin
# 박원규님의 MoniWiki 의 vim.php 의 코드를 흉내내었음.
#
# usage :
# {{{#!vim sh|c|sh|.. [number]
# some codes
# }}}

sub plugin_vim {
    my ($content, @opt) = @_;
    my $vim = "vim";        # PATH of vim
    my $tohtml = "syntax/2html.vim";
    my $text;
    my $status;
    my $option;

    my $type = "nosyntax";
    foreach my $opt (@opt) {
        if ($opt eq "number") {
            $option='+"set number" ';
        } elsif ($opt =~ /^\w+$/) {
            $type = $opt;
        }
    }
    $content =~ s/\r//g;

# html파일의 이름 결정
    my $hash;
    my $hasMD5 = eval "require Digest::MD5;";
    if ($hasMD5) {
        $hash = Digest::MD5::md5_base64($content.join('',@opt));
    } else {
        $hash = crypt($content, $HashKey);
    }
    $hash =~ s/(\W)/uc sprintf "_%02x", ord($1)/eg;

    my $hashhtml = "$hash.html";
    my $VimDir = "$UploadDir/vim";

    if ($hasMD5 and -f "$VimDir/$hashhtml" && not -z "$VimDir/$hashhtml") {
        # 이미 생성되어 캐쉬에 있음
        ($status, $text) = &ReadFile("$VimDir/$hashhtml");

        return $text if $status;
    }

    # 캐쉬에 없거나, 읽는 데 실패하면 새로 작성
    &CreateDir($UploadDir);
    &CreateDir($VimDir);

    my $hashdir = "$TempDir/$hash";
    if (not -d $hashdir) {
        mkdir($hashdir, 0775) or return "[Unable to create $hash dir]";
    }

    my $pwd = `pwd`;
    $pwd =~ s/(.*)(\n|\r)*/$1/;

    chdir ($hashdir);

# html 생성
    my $tmpi = "$hash.in";
    my $tmpo = "$hash.out";
    open (OUT, ">$tmpi") or return "[Unable to open $tmpi file]";
    print OUT  $content;
    close(OUT);

    open SAVEOUT, ">&STDOUT";
    open SAVEERR, ">&STDERR";
    open STDOUT, ">hash.log";
    open STDERR, ">&STDOUT";

    qx($vim -T xterm -e -s $tmpi +"set enc=$HttpCharset" +"syntax on" +"set syntax=$type" $option +"ru! $tohtml" +"wq! $tmpo" +q);

    close STDOUT;
    close STDERR;
    open STDOUT, ">&SAVEOUT";
    open STDERR, ">&SAVEERR";

    # html 가공 및 옮김
    ($status, $text) = &ReadFile("$tmpo");
    if (!$status) {
        return undef;
    }
    $text =~ s/<title>.*title>|<\/?head>|<\/?html>|<meta.*>|<\/?body.*>//g;
    $text =~ s/^.*?<pre>/<pre class='vim'>/gs;
    $text =~ s/^(\s|\n)*//gs;
    $text =~ s/(\s|\n)*$//gs;
    $text .= "\n";

    chdir($pwd);

    # 캐쉬에 저장
    if ($hasMD5 and open (OUT, ">$VimDir/$hashhtml")) {
        print OUT  $text;
        close(OUT);
    }

    unlink (glob("$hashdir/*")) or return "[unlink fail]";
    rmdir ($hashdir) or return "[rmdir fail]";

    return $text;
}

1;

1.3. wiki.css 수정

/* vim plugin */
PRE.vim {
    font: normal normal normal 105%/160% FixedSys, Lucida Console, Courier New, monospace;
    border: 1px solid silver;
    padding: 0.5em 0.5em 0.5em 0.5em;
    white-space:pre;
    text-align:justify;
    width:90%;

    background: black;
    color: #c0c0c0;
}

1.4. 추가 업데이트 내역

ext1.74e

• 1.74d 에서, 특수문자를 "%16진수"의 형태로 만들었더니 문제가 있어서, "_16진수"의 형태로 만들도록 함.
• number 옵션의 오작동 문제 수정
• 사용 가능한 신택스의 제한을 없앰

ext1.76a - 미리 보기를 하면 \r 캐릭터 때문에 변환 후 "^M"이 출력되는 문제 수정

ext2.9a - 플러그인의 출력으로 나오는 pre 태그의 스타일을 UseModWiki스타일쉬트에서 지정할 수 있게 수정

ext2.26a - html_use_css=1 옵션을 주어서, font 태그를 쓰지 않고 span 태그와 스타일쉬트를 사용하는 형태로 변환하게 함. 구체적인 변경 내역은 [vim plugin - CSS를 사용하도록 수정 · 55f970b · gypark/UseModKr] 참고

1.5. 사용자 의견