Perl/Configuring

1. Mastering Perl 에서

1.1. 하지 말아야 할 일 (Things Not to Do)

1.1.1. 코드를 별도의 파일에 저장 (Code in a Separate File)

1.2. 더 나은 방법들 (Better Ways)

1.2.1. 환경 변수 (Environment Variables)

1.2.2. 특별한 환경 변수 (Special Environment Variables)

1.2.3. 별도의 출력 (Turning on Extra Output)

1.3. 명령행 스위치 (Command-line Switches)

1.3.1. -s 스위치 (The -s Switch)

1.3.2. Getopt::Std

1.3.3. Getopt::Long

1.4. 설정 파일 (Configuration Files)

1.4.1. ConfigReader::Simple

1.4.2. Config::IniFiles

1.4.3. Config::Scoped

1.4.4. AppConfig

1.4.5. 그 외의 설정 포맷 (Other Configuration Formats)

1.5. 스크립트를 여러 가지 이름으로 실행 (Scripts with a Different Name)

1.6. 대화식 / 비대화식 프로그램 (Interactive and Noninteractive Programs)

1.7. perl의 Config 모듈 (perl's Config)

1.7.1. 여러가지 운영체제 (Different Operating Systems)

1.8. 읽어볼 글들 (Further Reading)

1. Mastering Perl 에서

1.1. 하지 말아야 할 일 (Things Not to Do)

• 수정하면 안 될 코드까지 수정할 수 있다.
• 오타 등의 이유로 문법 에러를 일으킬 수 있다.
• 프로그램을 여러 기계에 설치하여 사용할 때 서로 다른 버전을 사용하게 될 수도 있고, 이 경우 프로그램을 업데이트할 때마다 각각의 버전들을 일일이 수정해야 한다.

#!/usr/bin/perl
use strict;
use warnings;

my $Debug   = 0;
my $Verbose = 1;
my $Email   = 'alice@example.com';
my $DB      = 'DBI:mysql';

#### DON'T EDIT BEYOND THIS LINE !!! ###

use constant PI => 3.14159;

my $radius = 1;
my $circumference = 2 * PI * $radius;

use Readonly;

Readonly::Scalar my $Pi        => 3.14159;
Readonly::Array  my @Fibonacci => qw( 1 1 2 3 5 8 13 21 );
Readonly::Hash   my %Natural   => ( e => 2.72, Pi => 3.14, Phi => 1.618 );

use 5.8;
use Readonly;

Readonly my $Pi        => 3.14159;
Readonly my @Fibonacci => qw(1 1 2 3 5 8 13 21 );
Readonly my %Natural   => ( e => 2.72, Pi => 3.14, Phi => 1.618 );

1.1.1. 코드를 별도의 파일에 저장 (Code in a Separate File)

• 스코프 문제 때문에 렉시컬 변수를 사용할 수 없다.
• use vars 선언을 메인 프로그램을 컴파일하기 전에 처리해야 하므로 BEGIN 블럭에 넣어야 한다.

# config.pl
use vars qw( $Debug $Verbose $Email $DB );

$Debug   = 0;
$Verbose = 1;
$Email   = 'alice@example.com';
$DB      = 'DBI:mysql';

#!/usr/bin/perl
# 메인 프로그램

use strict;
use warnings;

BEGIN { require "config.pl"; }

1.2. 더 나은 방법들 (Better Ways)

1.2.1. 환경 변수 (Environment Variables)

#!/usr/bin/perl

print "Content-type: text/plain\n\n" if $ENV{REQUEST_METHOD};

foreach my $key ( sort keys %ENV )
    {
    printf "%-20s %s\n", $key, $ENV{$key};
    }

1.2.2. 특별한 환경 변수 (Special Environment Variables)

• PERL5OPT
  • perl을 실행할 때 명령행 인자로 이 변수의 값을 준 것처럼 동작한다.

% export PERL5OPT=w   # -w 스위치를 켠다.

• PERL5LIB
  • use lib 지시자의 역할. 모듈을 찾을 곳을 지정한다.
  • /모듈 참조

% export PERL5LIB=/Users/brian/lib/perl5

1.2.3. 별도의 출력 (Turning on Extra Output)

• 코드를 따로 고치지 않고 환경 변수를 수정하는 것만으로 이런 동작을 지시

# 이번 한번만 적용
$ DEBUG=1 ./program.pl
# 또는 이 세션 내내 적용
$ export DEBUG=1
$ ./program.pl

#!/usr/bin/perl
use strict;
use warnings;

my $Debug   = $ENV{DEBUG};
my $Verbose = $ENV{VERBOSE};

...

print "Starting processing\n" if $Verbose;

...

warn "Stopping program unexpectedly" if $Debug;

my $Debug   = $ENV{DEBUG}   || 0;
my $Verbose = $ENV{VERBOSE} || 1;

my $Debug   = defined $ENV{DEBUG} ? $ENV{DEBUG} : 0;
my $Verbose = defined $ENV{VERBOSE} ? $ENV{VERBOSE} : 1;

my $Verbose = $ENV{VERBOSE} // 1;

my $Debug   = $ENV{DEBUG}   || 0;
my $Verbose = $ENV{VERBOSE} || $ENV{DEBUG} || 0;

1.3. 명령행 스위치 (Command-line Switches)

• Getopt::Easy
• Getopt::Std
• Perl의 -s 스위치

% foo -i -t -r

• Getopt::Easy
• Getopt::Std
• Getopt::Mixed
• Perl의 -s 스위치

% foo -i -t -d/usr/local
% foo -i -t -d=/usr/local
% foo -i -t -d /usr/local

• Getopt::Easy
• Getopt::Mixed
• Getopt::Std

% foo -itr

• Perl의 -s 스위치

% foo -debug -verbose=1

• Getopt::Attribute
• Getopt::Long
• Getopts::Mixed

% foo --debug=1 -i -t
% foo --debug=1 -it

• Getopt::Long
• Getopts::Mixed
• -s 스위치

% foo -i -t --debug -- --this_is_an_argument

• Getopt::Lucid
• Getopts::Mixed

% foo -d
% foo --debug

• Getopt::Declare

% foo input=bar.txt --line 10-20

1.3.1. -s 스위치 (The -s Switch)

• 프로그램 스위치를 패키지 변수로 변환
• 다음 두 가지 형태를 지원
  • 싱글 하이픈 + 문자열
  • 더블 하이픈 + 문자열 ( 이 경우 싱글 하이픈 + 하이픈으로 시작하는 문자열의 형태로 인식 )

#!/usr/bin/perl -sw
# perl-s-abc.pl
use strict;

use vars qw( $a $abc );

print "The value of the -a switch is [$a]\n";
print "The value of the -abc switch is [$abc]\n";

• 값이 없는 스위치는 값을 1로 설정한다.
• "스위치=값" 형태로 값을 주면 그 값으로 설정한다.

% perl -s ./perl-s-abc.pl -abc=fred -a
The value of the -a switch is [1]
The value of the -abc switch is [fred]

• 더블 하이픈을 사용할 경우는 변수의 이름이 하이픈으로 시작하게 되므로, strict 를 사용할 경우 refs 를 꺼서 심볼릭 레퍼런스를 허용해 주어야 한다.

#!/usr/bin/perl -s
# perl-s-debug.pl
use strict;

{
no strict 'refs';
print "The value of the --debug switch is [${'-debug'}]\n";
print "The value of the --help switch is [${'-help'}]\n";
}

% perl -s ./perl-s-debug.pl --debug=11
The value of the --debug switch is [11]
The value of the --help switch is []

1.3.2. Getopt::Std

• 단일 문자 스위치 지원
  • 클러스터링 가능
  • 값 할당 가능

• getopt
  • getopt( 스위치 문자들로 이뤄진 스트링, 스위치 문자를 키로 하고 스위치 값을 값으로 하는 해쉬의 레퍼런스 )
  • 스위치 뒤에 값이 오면 값을 할당. 그렇지 않으면 아무 값도 할당하지 않음
  • 두번째 인자가 없을 경우는 패키지 변수에 할당 ( $opt_스위치문자 ) - 권장하지 않음

#!/usr/bin/perl
# getopt-std.pl
use strict;

use Getopt::Std;

getopt('dog', \ my %opts );

print <<"HERE";
The value of
    d   $opts{d}
    o   $opts{o}
    g   $opts{g}
HERE

$ perl getopt-std.pl -d 1
The value of
        d       1  <-- 값이 할당된다
        o
        g

$ perl getopt-std.pl -d
The value of
        d           <-- 스위치를 켰지만 값이 할당되지 않는다
        o
        g

• getopts
  • getopts( 문자열, 해쉬 레퍼런스 )
  • 값이 필요없는 스위치 지원 ( 켜져 있으면 1로 세팅 )
  • 값이 필요한 스위치는 문자 뒤에 콜론을 붙여서 표시

#!/usr/bin/perl
# getopts-std.pl

use Getopt::Std;

getopts('dog:', \ my %opts );   # -g 스위치는 값이 필요함

print <<"HERE";
The value of
    d   $opts{d}
    o   $opts{o}
    g   $opts{g}
HERE

$ perl getopts-std.pl -g foo -d
The value of
d       1
o
g       foo

값이 필요한 스위치 뒤에 값을 넣지 않으면 잘못된 결과
% ./getopts.pl -g -d -o         <-- "-d"는 -g 스위치의 값으로 간주된다
The value of
d
o        1
g       -d

반대로 값이 필요없는 스위치 뒤에 값을 넣으면 그 시점에서 getopts의 인자처리가 종료됨
$ perl getopts-std.pl  -d foo -g bar -o
The value of
        d       1
        o
        g

1.3.3. Getopt::Long

• 단일 문자 스위치
• 복수 문자 스위치
• 더블 하이픈으로 시작하는 스위치
• alias 지원

• GetOptions ( 키-값 쌍의 리스트 )
  • 키 - 스위치 이름
  • 값 - 해당 스위치의 값을 담을 변수의 레퍼런스

#!/usr/bin/perl
# getoptions-v.pl

use Getopt::Long;

my $result = GetOptions(
    'debug|d'   => \ my $debug,
    'verbose|v' => \ my $verbose,
    );

print <<"HERE";
The value of
    debug               $debug
    verbose             $verbose
HERE

• 'debug|d' - '|'로 구분하여 alias 지정가능

주인장 보충:

• 스위치 이름이 "debug"일 때는, "d", "de", "deb", "debu" 까지가 다 자동으로 인식이 된다. 따라서 굳이 "d"를 명시해 줄 필요는 없다.
• 만일 "delay"라는 스위치도 존재한다면, "de"까지는 두 스위치에 겹치기 때문에 인식하지 않는다.
• alias는 여러 개를 병기할 수도 있고, 두 글자 이상이어도 된다. 예: "debug|a|bc"

$ perl getoptions-v.pl -verbose
The value of
        debug
        verbose         1

$ perl getoptions-v.pl -v
The value of
        debug
        verbose         1

$ perl getoptions-v.pl -v -d
The value of
        debug           1
        verbose         1

$ perl getoptions-v.pl -v -debug
The value of
        debug           1
        verbose         1

$ perl getoptions-v.pl -v --debug
The value of
        debug           1
        verbose         1

• 값을 주어야 하는 스위치는 이름 뒤에 "="를 붙여서 표시. =s는 스트링. =i는 정수.
  • 잘못된 값을 줄 경우 경고

#!/usr/bin/perl
# getopt-long-args.pl

use Getopt::Long;

my $result = GetOptions(
    "file=s" => \ my $file,
    "line=i" => \ my $line,
    );

print <<"HERE";
The value of
    file                $file
    line                $line
HERE

$ perl getopt-long-args.pl -line=-9
The value of
        file
        line            -9
$ perl getopt-long-args.pl -line=9.9
Value "9.9" invalid for option line (number expected)
The value of
        file
        line

• 여러 개의 값을 받는 스위치의 경우는 "@"로 표시
  • 인자를 줄 때는 스위치를 매번 명시해야 함

#!/usr/bin/perl
# getopt-long-mult.pl

use Getopt::Long;

my $result = GetOptions(
    "file=s@" => \ my @files,
    );


{
local $" = ", ";

print <<"HERE";
The value of
    file                @files
HERE
}

$ perl getopt-long-mult.pl --file foo --file bar
The value of
        file            foo, bar

1.4. 설정 파일 (Configuration Files)

1.4.1. ConfigReader::Simple

• ConfigReader::Simple

# configreader-simple.txt
file=foo.dat
line=453
field value
field2 = value2
long_continued_field This is a long \
    line spanning two lines

#!/usr/bin/perl
# configreader-simple.pl

use ConfigReader::Simple;

my $config = ConfigReader::Simple->new(
    "configreader-simple.txt" );
die "Could not read config! $ConfigReader::Simple::ERROR\n"
    unless ref $config;

print "The line number is ", $config->get( "line" ), "\n";

1.4.2. Config::IniFiles

• Config::IniFiles
  • MS윈도우의 INI파일 형식을 처리

[Debugging]
;ComplainNeedlessly=1
ShowPodErrors=1

[Network]
email=brian.d.foy@gmail.com

[Book]
title=Mastering Perl
publisher=O'Reilly Media
author=brian d foy

#!/usr/bin/perl
# config-ini.pl

use Config::IniFiles;

my $file = "mastering_perl.ini";

my $ini = Config::IniFiles->new(
    -file    => $file
    ) or die "Could not open $file!";

my $email = $ini->val( 'Network', 'email' );
my $author = $ini->val( 'Book', 'author' );

print "Kindly send complaints to $author ($email)\n";

1.4.3. Config::Scoped

• INI와 비슷한데, 섹션을 중첩할 수 있으며, 한 키에 여러 개의 값을 지정할 수 있음

book {
    author = {
        name="brian d foy";
        email="brian.d.foy@gmail.com";
        };
    title="Mastering Perl";
    publisher="O'Reilly Media";
}

#!/usr/bin/perl
# config-scoped.pl

use Config::Scoped;

my $config = Config::Scoped->new( file => 'config-scoped.txt' )->parse;
die "Could not read config!\n" unless ref $config;

print "The author is ", $config->{book}{author}{name}, "\n";

1.4.4. AppConfig

• AppConfig

• 명령행 옵션, 설정 파일, 환경 변수, CGI 파라메터 등을 일괄적으로 처리 가능
• 설정파일의 경우 ConfigReader::Simple에서 지원하는 라인 기반 포맷, INI 포맷, 기타 다양한 포맷 지원

• INI파일을 사용하는 예
  • 다양한 포맷을 지원하기 때문에, 사용가능한 스위치와 스위치에 할당될 수 있는 값의 형태 등을 알려줘야 한다.
  • Getopt::Long에서 쓰는 포맷 문법을 사용.
  • INI 포맷의 경우 섹션과 키의 이름을 flatten함

#!/usr/bin/perl
# appconfig-ini.pl

use AppConfig;

my $config = AppConfig->new;

$config->define( 'network_email=s'  );
$config->define( 'book_author=s'    );
$config->define( 'book_title=s'     );
$config->define( 'book_publisher=s' );

$config->file( 'config.ini' );

my $email  = $config->get( 'network_email' );
my $author = $config->get( 'book_author' );

print "Kindly send complaints to $author ($email)\n";

• args() 함수를 써서 @ARGV에 들어온 명령행 옵션들을 Getopt::Long을 이용하여 처리

#!/usr/bin/perl
# appconfig-args.pl

use AppConfig;

my $config = AppConfig->new;

$config->define( 'network_email=s'  );
$config->define( 'book_author=s'    );
$config->define( 'book_title=s'     );
$config->define( 'book_publisher=s' );

$config->file( 'config.ini' );

$config->args();

my $email  = $config->get( 'network_email' );
my $author = $config->get( 'book_author' );

print "Kindly send complaints to $author ($email)\n";

$ perl appconfig-args.pl
Kindly send complaints to brian d foy (brian.d.foy@gmail.com)

$ perl appconfig-args.pl -network_email bdfoy@cpan.org     <-- network_email 스위치를 override
Kindly send complaints to brian d foy (bdfoy@cpan.org)

1.4.5. 그 외의 설정 포맷 (Other Configuration Formats)

• Win32::Registry - 윈도우 레지스트리
• Mac::PropertyList - Max OS X의 plist 포맷
• Config::ApacheFile - 아파치 설정 포맷

1.5. 스크립트를 여러 가지 이름으로 실행 (Scripts with a Different Name)

if( $0 eq ... )    { ... do this init ... }
elsif( $0 eq ... ) { ... do this init ... }
...
else               { ... default init ... }

#!/bin/sh

DEBUG=0
VERBOSE=0
DBI_PROFILE=2

./program -n some_value -m some_other_value

1.6. 대화식 / 비대화식 프로그램 (Interactive and Noninteractive Programs)

• 파일 테스트 연산자 -t 를 사용하여 표준입력과 표준출력이 터미널에 연결되어 있는지를 검사

$ perl -le 'print "Interactive!" if( -t STDIN and -t STDOUT )'
Interactive!

• IO::Interactive
  • is_interactive - 대화식으로 실행되는 중이면 true

use IO::Interactive qw(is_interactive);

my $can_talk = is_interactive();
print "Hello World!\n" if $can_talk;

• interactive - 대화식으로 실행되는 중이면 STDOUT 파일핸들을 반환. 아니면 null 파일핸들 반환

use IO::Interactive qw(interactive);

print { interactive() } "Hello World!\n";

1.7. perl의 Config 모듈 (perl's Config)

• Config

#!/usr/bin/perl

use Config;

print "Send complaints to $Config{cf_email}\n";

print "I was compiled on $Config{myhostname}.$Config{mydomain}\n";

print "has thread support\n" if $Config{usethreads};

1.7.1. 여러가지 운영체제 (Different Operating Systems)

• $^O , $Config{'osname'} 현재 실행되고 있는 OS 이름
• $Config{'archname'} - 좀 더 상세한 정보

package File::Spec;

use strict;
use vars qw(@ISA $VERSION);

$VERSION = '0.87';

my %module = (MacOS   => 'Mac',
              MSWin32 => 'Win32',
              os2     => 'OS2',
              VMS     => 'VMS',
              epoc    => 'Epoc',
              NetWare => 'Win32', # Yes, File::Spec::Win32 works on NetWare.
              dos     => 'OS2',   # Yes, File::Spec::OS2 works on DJGPP.
              cygwin  => 'Cygwin');


my $module = $module{$^O} || 'Unix';

require "File/Spec/$module.pm";
@ISA = ("File::Spec::$module");

1;

1.8. 읽어볼 글들 (Further Reading)

• perlport
• AppConfig에 관하여
  • [Cultured Perl: Application configuration with Perl]
  • [Cultured Perl: Application configuration with Perl, Part 2]
  • [Cultured Perl: Complex layered configurations with AppConfig]
• Config::Scoped에 관하여
  • [Nicer Configuration Files (Jul 05)]