Perl/익명서브루틴의재귀호출

1. 개요

2. 재귀호출하는 익명 서브루틴을 만들 때의 문제점

3. 메모리 누수 문제 해결을 위한 코드

4. CPAN 모듈 사용

5. 참고 문서

6. Comments

1. 개요

2. 재귀호출하는 익명 서브루틴을 만들 때의 문제점

sub fac {
    my $n = shift;
    return 1 if $n == 1;
    return $n * fac( $n-1 );
}

print "10! = ", fac(10), "\n";

my $fac = sub {
    my $n = shift;
    return 1 if $n == 1;
    return $n * $fac->( $n-1 ); # 여기서 컴파일 에러
};

print "10! = ", $fac->(10), "\n";

• 변수 $fac은 아직 정의되지 않은 상태이기 때문에 컴파일 시점에 에러가 난다.

my $fac;
$fac = sub {
    my $n = shift;
    return 1 if $n == 1;
    return $n * $fac->( $n-1 );
};

print "10! = ", $fac->(10), "\n";

foreach ( 0 .. 100000 ) {
    my $fac;
    $fac = sub {
        my $n = shift;
        return 1 if $n == 1;
        return $n * $fac->( $n-1 );
    };

    $fac->(10);
#     print "10! = ", $fac->(10), "\n";
}

print "hit any key:";
<STDIN>;

• 루프 안에서 익명 서브루틴을 생성하고 호출하는 과정을 반복한다. 매 반복 때마다 $fac과 저 익명 서브루틴은 소멸되어야 하지만, 실제로는 소멸되지 않고 계속 쌓인다.
• 루프를 십만 번 돌고 나면, 종료 전에 메모리 워킹셋 사이즈가 300MB를 차지한다:

3. 메모리 누수 문제 해결을 위한 코드

use Scalar::Util qw/weaken/;

foreach ( 0 .. 100000 ) {
    my $fac;
    $fac = sub {
        my $n = shift;
        return 1 if $n == 1;
        return $n * $fac->( $n-1 );
    };

    $fac->(10);
    weaken($fac);
#     print "10! = ", $fac->(10), "\n";
}

• 이제는 3MB밖에 차지하지 않는다.

use Scalar::Util qw/weaken/;

foreach ( 0 .. 100000 ) {
    my ($fac, $f);
    $f = $fac = sub {        # 변수가 하나 더 있다
        my $n = shift;
        return 1 if $n == 1;
        return $n * $fac->( $n-1 );
    };

    weaken($fac);            # $fac->()을 부르기 전에 weaken()
    $fac->(10);
#     print "10! = ", $fac->(10), "\n";
}

• $f변수를 추가로 사용하여 레퍼런스 카운트를 1늘렸다.

• 메모리 사용량은 앞의 경우와 동일하다. (KB단위라서, 정확히 동일하지 않을 수도 있다)

4. CPAN 모듈 사용

use Sub::Recursive;

foreach ( 0 .. 100000 ) {
    my $fac = recursive {
        my $n = shift;
        return 1 if $n == 1;
        return $n * $REC->( $n-1 );
    };

    $fac->(10);
#     print "10! = ", $fac->(10), "\n";
}

• sub 키워드 대신에 recursive를 사용
• 현재 서브루틴의 레퍼런스를 담는 $REC 변수가 익스포트된다.

• 역시 메모리 사용량은 앞에서와 유사하다.

use Sub::Current;

foreach ( 0 .. 100000 ) {
    my $fac = sub {
        my $n = shift;
        return 1 if $n == 1;
        return $n * ROUTINE->( $n-1 );
    };

    $fac->(10);
#     print "10! = ", $fac->(10), "\n";
}

• 현재 수행중인 서브루틴의 레퍼런스를 반환하는 ROUTINE->()을 제공한다.

• 역시 메모리 사용량은 앞에서와 유사하다.

• 일단 익명 서브루틴을 만든 후에, 호출만 십만번 반복하게 했을 때는 Sub::Recursive 가 더 빨랐다. 그리고 5!, 10!, 15!, 20!, 25!을 계산할 때 속도 차이가 더 벌어졌다.
• 익명 서브루틴을 생성하고 한 번 호출하는 과정 전체를 루프 안에 넣고 십만번 반복했을 때는, 5!,10!,15! 계산 때는 Sub::Current 가 더 빨랐고, 20!,25! 때는 Sub::Recursive가 점점 더 빨라졌다.
• 요컨데 이 결과만 놓고 보면, 익명 서브루틴을 생성하는 과정에서는 Sub::Current가 더 빠른데, 생성한 서브루틴을 호출할 때, 특히 재귀 호출의 단계가 깊어질수록 Sub::Recursive가 더 빨라진다.

5. 참고 문서

• [1] Holy Zarquon's Singing Fish at blogs.perl.org: Fun with recursive anonymous subroutines
• Sub::Recursive
• Sub::Current
• [Use __SUB__ to get a reference to the current subroutine | The Effective Perler] - 5.16부터는 __SUB__ 키워드 사용 가능

6. Comments