Perl/파일

1. 기본적인 입출력

1.1. 읽기쓰기 모드에서 읽기와 쓰기의 전환

1.2. chomp

1.3. 인자 3개 형태의 open을 쓰자

1.4. 파일핸들도 렉시컬 변수를 쓸 수 있다

2. <ARGV>

3. $/

4. 파일 핸들끼리의 할당

4.1. 파일 핸들을 서브루틴의 인자로 넘기기

5. 바이너리 파일 입출력

6. select

7. 버퍼링

8. 디렉토리

8.1. chdir

8.2. Globbing

8.3. Directory Handle

9. 파일 관련 테스트 연산자

10. stat, lstat

11. special underscore filehandle

12. 파일, 디렉토리 관련 명령어와 함수

13. 인코딩 지정

14. 스트링 변수를 파일처럼 읽거나 쓰기

15. 기타

16. Comments

1. 기본적인 입출력

• open FILEHANDLE, MODE, EXPR
  • EXPR 은 주로 파일명
  • MODE
    • < 또는 없음 : 읽기모드
    • > : 쓰기모드. 파일이 존재할 경우 내용을 지움
    • >> : 추가모드. 파일이 존재할 경우 마지막에 내용을 추가함
    • +< : 읽기, 쓰기
    • +> : 읽기, 쓰기. 파일이 존재할 경우 내용을 지움
    • +>> : 읽기, 추가하기
    • |- : 출력 파이프
    • -| : 입력 파이프
  • open에 실패하면 $! 변수에 에러 내용이 담긴다.
• 읽거나 쓰고
  • @allLine = <fileHandle>; 파일 전부를 읽기
  • $aLine = <fileHandle>; 한 줄 읽기
  • print fileHandle "안녕"; 출력
• close( fileHandle ); 로 닫는다.

open my $fileHandle, "<", $fileName ) or die "Cannot open $fileName: $!";
while( $aLine = <$fileHandle> )
{
  print $aLine;
}
close $fileHandle;

# 변수를 생략하면 $_ 사용
while (<$fileHandle>) {    # (defined ($_ = <$fileHandle>))
  print "$_";
}

open my $fileHandle, "<", $fileName or die "Cannot open $fileName: $!";
@allLines = <$fileHandle>;
close $fileHandle;

local $/ = undef;
open my $fileHandle, "<", $fileName or die "Cannot open $fileName: $!";
$allLines = <$fileHandle>;
close $fileHandle;

1.1. 읽기쓰기 모드에서 읽기와 쓰기의 전환

1.2. chomp

$line = <STDIN>;
chomp $line;
# 한 줄로
chomp ($line = <STDIN>);

## 리스트의 경우는, 각 엘리먼트의 "\n"을 일괄 제거
chomp (@lines = <STDIN>);

1.3. 인자 3개 형태의 open을 쓰자

open FH, $filename;       # 이건 위험
open FH, "< $filename";   # 입력의 경우 "<"가 없어도 되지만 명시하는게 안전
# perl 5.6 이상부터는 별개의 인자로 줄 수 있음
open FH, "<", $filename;  # 이것을 권장

1.4. 파일핸들도 렉시컬 변수를 쓸 수 있다

open FH, "<", $filename;      # FH 는 전역적인 파일핸들
open my $fh, "<", $filename;  # $fh 는 렉시컬 변수. 권장

2. <ARGV>

#!/usr/bin/perl
# nl3.plx
use warnings;
use strict;

my $lineno;
my $current = "";

while (<>) {
   if ($current ne $ARGV) {
      $current = $ARGV;
      print "\n\t\tFile: $ARGV\n\n";
      $lineno=1;
   }

   print $lineno++;
   print ": $_";
}

3. $/

• $/ = ""; - blank line을 구분자로 함 (단락 단위로 읽는다고 볼 수 있다)
• $/ = undef; - file 내용 전체를 하나의 스칼라로 읽음
• $/ = \1024; (양수의 레퍼런스) - 한 번에 1024바이트를 읽음3
• chomp 의 역할은 인자의 제일 뒤에 $/ 변수의 값이 있는 경우 그것을 제거4

4. 파일 핸들끼리의 할당

if (defined $input) {
   open INPUT, $input or die "Couldn't open file $input: $!\n";
} else {
   *INPUT = *STDIN;   # typeglob을 사용해야 함
}

4.1. 파일 핸들을 서브루틴의 인자로 넘기기

# typeglob 사용
sub say_hello {
   *WHERE = shift;
   print WHERE "Hi there!\n";
}
say_hello(*STDOUT);

## 또는
sub say_hello {
   my $fh = shift;  # 일반 변수에
   print $fh "Hi there!\n";
}
say_hello(*STDOUT); # 호출하는 쪽에서는 typeglob

5. 바이너리 파일 입출력

binmode FILEHANDLE;

6. select

select LOG;
print "blah blah...\n";   # LOG에 해당하는 파일로 출력된다.

select STDOUT;  # 표준출력으로 복원

7. 버퍼링

• $| = 0; - 운영체제의 버퍼링 사용 (기본값)
• $| = 1; - 버퍼링 사용하지 않음

$| = 1;
for (1...20) {
   print ".";   # 버퍼링이 사용될 경우, 20초 후에 한꺼번에 20개의 "."이 출력된다.
   sleep 1;
}
print "\n";

8. 디렉토리

8.1. chdir

• 변경된 디렉토리는 자식 프로세스에 상속됨
• 파라메터가 생략되었을 경우는 $_을 쓰는 게 아니라 현재 사용자의 홈 디렉토리로 변경 시도
• 쉘의 cd에서 가능한 ~username 형식은 지원하지 않는다. - 이것은 OS가 아니라 쉘의 기능

8.2. Globbing

my @all_files = glob "*";
my @pm_files = glob "*.pm";
my @all_files_including_dot = glob ".* *";  # 패턴들은 공백으로 구분
# 또는
my @all_files = <*>;

8.3. Directory Handle

• readdir의 리턴값은 경로명을 제외한 파일명만 들어 있으니 주의

opendir DH, "." or die "Couldn't open the current directory: $!";
while ($_ = readdir(DH)) {   # readdir은 파일명을 하나씩 반환
        next if $_ eq "." or $_ eq "..";
        print $_, " " x (30-length($_));
        print "d" if -d $_;
        print "r" if -r _;   # "_"는 "마지막으로 테스트한 파일"을 의미
        # ...
}
closedir DH;
}

9. 파일 관련 테스트 연산자

10. stat, lstat

    my ($dev, $ino, $mode, $nlink, $uid, $gid, $rdev,
      $size, $atime, $mtime, $ctime, $blksize, $blocks)
        = stat($filename);

11. special underscore filehandle

push @big_old_files, $_
        if (-s) > 100_000 and -A _ > 90;        # -A 의 인자로 "_"

12. 파일, 디렉토리 관련 명령어와 함수

• rename OLDNAME, NEWNAME
• unlink LIST

                   $cnt = unlink ’a’, ’b’, ’c’;
                   unlink @goners;
                   unlink <*.bak>;

• link OLDFILE, NEWFILE - 하드 링크
• symlink OLDFILE, NEWFILE - 심볼릭 링크
  • readlink EXPR - 심볼릭 링크의 값을 읽음

• mkdir FILENAME, MASK
• rmdir FILENAME
  • 빈 디렉토리만 삭제 가능
  • File::Path 모듈의 rmtree를 쓰면 편하다

• chmod LIST
  • ex) chmod 0755, "fred", "barney";
• chown LIST
  • ex) chown $user, $group, @filenames;
  • user ID와 group ID는 숫자. 이름으로부터 얻고 싶다면 getpwnam, getgrnam 사용하여 해당 숫자 값을 먼저 얻을 것
• utime LIST - 액세스 시각과 수정 시각 변경
  • ex) utime $atime, $mtime, @filenames;

13. 인코딩 지정

# UTF-8로 저장된 파일을 읽어서 디코드
open my $fh, '<:utf8', 'file.txt';

# UTF-8로 저장된 파일을 읽어서 디코드 - 정합성 체크까지
open my $fh, '<:encoding(UTF-8)', 'file.txt';

# EUC-KR로 저장된 파일을 읽어서 디코드
open my $fh, '<:encoding(EUC-KR)', 'file.txt';

# UTF-8로 인코드하여 저장
open my $fh, '>:utf8', 'file.txt';

# 이미 열려 있는 파일 핸들은 binmode 로 지정 가능
binmode STDIN,':utf8';

14. 스트링 변수를 파일처럼 읽거나 쓰기

my $string;
open my $fh, ">", \ $string;

# 위 두 줄을 아래처럼 쓸 수도 있음
open my $fh, ">", \ my $string;

# 일반적으로 파일을 다루듯이 쓸 수 있음
print $fh "Hello";

15. 기타

• [Suffering from Buffering?]

16. Comments